home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / op27c < prev    next >
Encoding:
Text File  |  1996-07-09  |  3.1 KB  |  112 lines
  1. *
  2. * Linear Technology OP27C op amp model (with calls for OP27G, OP227C, OP227G)
  3. * Written: 11-21-1989 Type: Bipolar npn input, internal comp.
  4. * OP27C updated from original model on 06-20-1990
  5. * Typical specs: 
  6. *       Ref. OP-27 data sheet, LTC 1990 databook p2-345
  7. * Comments:
  8. *       Uses extended phase compensation; input differential mode clamp.
  9. * 
  10. * Connections: + - V+V-O 
  11. .SUBCKT OP27C 3 2 7 4 6
  12. RC1 7 80 6.6315E+02 
  13. RC2 7 90 6.6315E+02
  14. Q1 80 2 10 QM1
  15. Q2 90 3 11 QM2
  16. * 
  17. C1 80 91 200E-12
  18. RXC1 91 90 50
  19. CXC1 91 90 500E-12
  20. C2 8 98 4.000E-12
  21. RXC2 8 98 4.00K
  22. CXC2 1 98 27.000E-12
  23. *
  24. CIN 3 2 5E-12
  25. DDM1 2 104 DM2
  26. DDM3 104 3 DM2
  27. DDM2 3 105 DM2
  28. DDM4 105 2 DM2
  29. RE1 10 12 -2.6233E+01
  30. RE2 11 12 -2.6233E+01
  31. IEE 12 4 7.5030E-05
  32. RE 12 0 2.666E+06
  33. CE 12 0 1.579E-12
  34. GCM 0 8 12 0 7.558E-10
  35. GA 8 0 80 90 1.5080E-03
  36. R2 8 0 1.000E+05
  37. GB 1 0 8 0 1.9176E+03
  38. RO2 1 0 6.900E+01
  39. *
  40. RS 1 6 1
  41. ECL 18 0 1 6 2.828E+01
  42. GCL 0 8 20 0 1
  43. RCL 20 0 1E3
  44. D1 18 20 DM1
  45. D2 20 18 DM1
  46. *
  47. D3A 131 70 DM3
  48. D3B 13 131 DM3
  49. GPL 0 8 70 7 1
  50. VC 13 6 3.0909
  51. RPLA 7 70 1E4
  52. RPLB 7 131 1E5
  53. D4A 60 141 DM3
  54. D4B 141 14 DM3
  55. GNL 0 8 60 4 1
  56. VE 6 14 3.0909
  57. RNLA 60 4 1E4
  58. RNLB 141 4 1E5
  59. *
  60. IP 7 4 2.625E-03
  61. DSUB 4 7 DM2 
  62. * MODELS 
  63. .MODEL QM1 NPN (IS=8.0000E-16 BF=2.0000E+03)
  64. .MODEL QM2 NPN (IS=8.0093E-16 BF=4.6667E+03)
  65. .MODEL DM1 D (IS=1.000E-19)
  66. .MODEL DM2 D (IS=8.000E-16)
  67. .MODEL DM3 D (IS=1.000E-20)
  68. .ENDS OP27C
  69. * 
  70. .SUBCKT OP27G 3 2 7 4 6
  71. X_OP27G 3 2 7 4 6 OP27C
  72. .ENDS OP27G
  73. * 
  74. .SUBCKT OP227C 3 2 7 4 6
  75. X_OP227C 3 2 7 4 6 OP27C
  76. .ENDS OP227C
  77. * 
  78. .SUBCKT OP227G 3 2 7 4 6
  79. X_OP227G 3 2 7 4 6 OP27C
  80. .ENDS OP227G
  81. * 
  82. * - - - - - * FINI OP27C FAMILY * - - - - - *
  83. ***
  84. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1990
  85. *                       All rights reserved.
  86. * 
  87. *   Linear Technology Corporation hereby grants the users of this
  88. * macromodel a non-exclusive, nontransferrable license to use this
  89. *            macromodel under the following conditions:
  90. * 
  91. * The user agrees that this macromodel is licensed from Linear
  92. * Technology and agrees that the macromodel may be used, loaned,
  93. * given away or included in other model libraries as long as this
  94. * notice and the model in its entirety and unchanged is included.
  95. * No right to make derivative works or modifications to the
  96. * macromodel is granted hereby.  All such rights are reserved.
  97. * 
  98. * This model is provided as is.  Linear Technology makes no
  99. * warranty, either expressed or implied about the suitability or
  100. * fitness of this model for any particular purpose.  In no event
  101. * will Linear Technology be liable for special, collateral,
  102. * incidental or consequential damages in connection with or arising
  103. * out of the use of this macromodel.  It should be remembered that
  104. * models are a simplification of the actual circuit.
  105. * 
  106. * Linear Technology reserves the right to change these macromodels
  107. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  108. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  109. * datasheets on the actual amplifiers or the latest macromodels.
  110. * 
  111. * ----------------------------------------------------------------------- *
  112.